LSAT: item response

Section 6 of the Law School Aptitude Test (LSAT) is a 5-item multiple choice test; students score 1 on each item for the correct answer and 0 otherwise, giving R = 32 possible response patterns.Boch and Lieberman (1970) present data on LSAT for N = 1000 students, part of which is shown below.

The above data may be analysed using the one-parameter Rasch model (see Andersen (1980), pp.253-254; Boch and Aitkin (1981)). The probability p_jk that student j responds correctly to item k is assumed to follow a logistic function parameterized by an `item difficulty' or threshold parameter α_k and a latent variable θ_j representing the student's underlying ability. The ability parameters are assumed to have a Normal distribution in the population of students. That is:

   logit(p_jk) = θ_{j -} α_{k, j = 1,...,1000; k = 1,...,5}
   
   θ_j ~ Normal(0, τ)

The above model is equivalent to the following random effects logistic regression:
   
   logit(p_jk) = βθ_{j -} α_{k, j = 1,...,1000; k = 1,...,5}
   
   θ_j ~ Normal(0, 1)
   
where β corresponds to the scale parameter (β² = τ) of the latent ability distribution. We assume a half-normal distribution with small precision for β_; this represents vague prior information but constrains β to be positive. Standard vague normal priors are assumed for the α_k's. Note that the location of the α_k's depend upon the mean of the prior distribution for θ_j which we have arbitrarily fixed to be zero. Alternatively, Boch and Aitkin ensure identifiability by imposing a sum-to-zero constraint on the α_k's. Hence we calculate a_k = α_k - α_bar to enable comparision of the BUGS posterior parameter estimates with the Boch and Aitkin marginal maximum likelihood estimates.
BUGS language for LSAT model


   model
   {
   # Calculate individual (binary) responses to each test from multinomial data
      for (j in 1 : culm[1]) {
         for (k in 1 : T) {
            r[j, k] <- response[1, k]
         }
      }
      for (i in 2 : R) {
         for (j in culm[i - 1] + 1 : culm[i]) {
            for (k in 1 : T) {
               r[j, k] <- response[i, k]
            }
         }
      }
   # Rasch model
      for (j in 1 : N) {
         for (k in 1 : T) {
            logit(p[j, k]) <- beta * theta[j] - alpha[k]
            r[j, k] ~ dbern(p[j, k])
         }
         theta[j] ~ dnorm(0, 1)
      }
   # Priors
      for (k in 1 : T) {
         alpha[k] ~ dnorm(0, 0.0001)
         a[k] <- alpha[k] - mean(alpha[])
      }
      beta ~ dunif(0, 1000)
   }

Note that the data are read into BUGS in the original multinomial format to economize on space and effort. The 5 times 1000 individual binary responses for each item and student are then created within BUGS using the index variable culm (read in from the data file), where culm[i] = cumulative number of students recording response patterns 1, 2, ..., i; i <= R.

NB when generating initial values do not check the fix founder box in the Specification Tool. If you do all the theta will be set to zero and beta will go to la-la land.
   Results